Text ausgehend von einem Feldwert bestimmen
Sie können in einer Spalte benutzerdefinierten Text anzeigen, der auf einer Bedingung oder verschiedenen Bedingungen basiert. Beispielsweise wäre eine Formel denkbar, die einen benutzerdefinierten Text anzeigt, wenn die Verkaufszahlen über einem bestimmten Wert liegen. Diese Formel überprüft den Wert "Verkauf_Februar" (ein Zahlenfeld), und zeigt Text an, der auf diesem Wert beruht:

@If(Verkauf_Februar>60000;"Guter Monat!";"")

Text ausgehend von einem Maskennamen bestimmen
In der Spalte "Betreff" der Ansicht "Alle Dokumente" in der Schablone "Mail" wird folgende Formel verwendet: (es wird eine Betreffzeile angezeigt, die auf der Maske basiert, mit der das Dokument erstellt wurde):

@If(Form = "NonDelivery Report"; "ZUSTELLUNGSFEHLER: " + FailureReason; Form = "Delivery Report"; "ZUGESTELLT: " + Subject; Form = "Return Receipt"; "EMPFANGEN: " + Subject; Form = "ReturnNonReceipt"; "NICHT EMPFANGEN: " + Subject; Subject)

Text und Datumswerte kombinieren
Sie können Text und Feldwerte in einer Spalte einer Datenbank für Terminplanung kombinieren, um die einzelnen Dokumente näher zu erläutern. In der folgenden Formel wird eine Textnachricht und ein Datum angezeigt. Dabei sind zwei Variationen möglich, abhängig von dem Wert im Feld "Sched". Der Parameter "D1S0" der Formel @Text ist eine Formatierungsoption, die überflüssige Informationen aus der Ansicht entfernt, indem nur Monat und Jahr des Datumsfeldes ohne Angabe des genauen Zeitpunkts angezeigt werden.

@If(Sched = "Besonderer Zeitplan"; "Besonderer Zeitplan für die Woche vom: " + @Text(Date; "D1S0"); "Mein regulärer Zeitplan ab " + @Text(@Modified; "D1S0"))

Text und Namen kombinieren
Die folgende Formel ergibt eines von drei möglichen Ergebnissen, basierend auf dem Status der Anfrage:

@If(Status="Zurückgewiesen";"Zurückgewiesen von " + LastApproveName; SignatureCount=0; "Originalanfrage";"Genehmigt von " + LastApproveName)

• Wurde die Anforderung zurückgewiesen, wird in der Spalte der Text "Zurückgewiesen von" in Verbindung mit dem Namen der Person angezeigt, die die Maske zuletzt signiert hat.
• Enthält die Anfrage keine Signaturen, (was bedeutet, dass kein Antragsprüfer die Anfrage bearbeitet hat,) wird in der Spalte der Text "Originalanfrage" angezeigt.
• Wurde die Anfrage genehmigt, wird in der Spalte der Text "Genehmigt von" in Verbindung mit dem Namen der Person angezeigt, die die Maske zuletzt signiert hat.

@Created

Erweiterbare Ebenen (Variation der einfachen Funktion)
Die einfache Funktion "Komprimieren/Erweitern" (+/-) verwendet @IsExpandable ohne Argumente. Wenn Sie ein + (Pluszeichen) anzeigen möchten, wenn ein Dokument Antworten enthält, aber kein - (Minuszeichen), wenn Antworten erweitert werden, können Sie die folgende Formel verwenden:

@IsExpandable("+";"")

Zwei Feldwerte in einer Spalte anzeigen
Um die Namen und Telefonnummern von Personen in einer einzigen Spalte anzuzeigen, erstellen Sie eine Spalte, die in aufsteigender Reihenfolge (empfohlene Reihenfolge für alphabetische Listen) sortiert wird. Die folgende Formel trennt die beiden Feldwerte durch ein Leerzeichen:

Name + " " + Phone

"Vorgetäuschte" Einrückungen erstellen
Wenn IBM® Lotus® Notes® Antwortdokumente einrückt, wird immer dieselbe Einrückung verwendet. Wenn Sie Dokumente in einer einfachen Ansicht ohne Antwortdokumente einrücken möchten oder wenn Sie Dokumenttitel in derselben Spalte unterschiedlich einrücken möchten, können Sie in einem Feld der Maske bestimmen, wie weit die einzelnen Dokumente eingerückt werden, und außerdem den Dokumenttiteln in der Ansicht anhand einer Spaltenformel Leerzeichen hinzufügen. Die folgende Formel rückt Dokumente auf drei verschiedene Arten ein, je nachdem, welchen Wert das Feld "Einrücken" enthält. Lautet der Wert im Feld "Einrücken" beispielsweise 2, werden dem Betreff des Dokuments in der Spalte 18 Leerzeichen vorangestellt.

@If(Einrücken = 1; @Repeat(" "; 12) + Betreff; Einrücken = 2; @Repeat(" "; 18) + Betreff; @Repeat(" "; 6) + Betreff)

Dokumente nummerieren
In einer Ansicht "Nach Autor" werden die einzelnen Dokumente innerhalb jeder Kategorie eines Autors nummeriert (z. B. 1., 2., 3.)

@IsCategory("";@DocNumber("") + ". ")

Entspricht die Zeile einer Kategorie (der Name des Autors), gibt @IsCategory eine Nullzeichenfolge ("") zurück. Ist die Zeile keine Kategorie, stellt sie ein Dokument dar. Dabei gibt @DocNumber eine Zeichenfolge zurück, die die Eintragsnummer des entsprechenden Dokuments angibt. Die vollständige Eintragsnummer eines Dokuments lautet etwa 1.1, 1.2, 1.3 usw. Wird die Eintragsnummer in Verbindung mit einer Nullzeichenfolge ("") benutzt, gibt @DocNumber die rechte äußerste Komponente der Eintragsnummer zurück. Die Formel fügt einen Punkt und ein Leerzeichen hinter der Zahl ein.

Spaltenfarben programmseitig festlegen
In Notes-Client Anwendungen können Sie die Hintergrundfarbe und die Textfarbe für eine Spalte programmseitig festlegen, indem Sie die Option "Wert als Farbe verwenden" im Register "Info" der InfoBox "Eigenschaften: Spalte" wählen und anschließend RGB-Werte im Programmierfenster als Wert für die Spalte angeben.

Hinweis Diese Funktion wird im Web unterstützt, Sie müssen die RGB-Werte der Farbe als Zahlen angeben (z. B. 255:0:255). Farbwerte im Textformat (z. B. "FF00FF") werden nicht unterstützt.

Wenn Sie einen Farbwertsatz angeben (drei durch Doppelpunkte voneinander getrennte Zahlen), wird durch die Farbe die Gestaltung des Textes definiert. Wenn Sie zwei Farbwertsätze angeben (sechs durch Doppelpunkte voneinander getrennte Zahlen), wird mit dem ersten Farbwertsatz die Hintergrundfarbe für die Spalte definiert und mit dem zweiten Farbwertsatz die Textfarbe. Die Farbe wirkt sich an der Stelle auf die Spalte aus, an der Sie den Farbwert festlegen, und alle Spalten rechts davon, bis Sie eine weitere Farbe festlegen.

Hinweis Werden die Farben auf -1:-1:-1 gesetzt, werden die Ansichts- und die Spalteneigenschaften zurückgesetzt.

Im nachstehenden Beispiel wird gezeigt, wie RGB-Farbwerte in Einzelsätzen und Paarsätzen verwendet werden können.

red := 255:0:0;
blue := 0:0:255;
yellow := 255:255:0;
pink := 255:193:253;
white := 255:255:255;
black :=  1:1:1;
apricot := 255:155:133;
plain:= 0:0:0;

@If (category = "Katzen";blue:red ;subcategory = "Halsbänder";pink;subcategory ="Leinen";black:plain;0:0:0);

Hinweis Sie müssen die Farbnamen nicht definieren. Sie können die numerischen Kombinationen direkt in eine Formel eingeben. Wenn Sie die Farben definieren, sehen Sie jedoch besser, was Sie tun, und die Wahrscheinlichkeit von Tippfehlern bei der häufigeren Verwendung einer Farbe wird verringert. Da das Definieren der Farben mit Wörtern einfacher ist als mit Zahlenkombinationen, werden die Daten selbst in den Farbspalten nicht angezeigt. Um die Kategorie "Katzen" beispielsweise in Rot anzuzeigen, benötigen Sie eine weitere Spalte zum Anzeigen der Kategorie.

Sie können auch den Spaltenwert auf einen Feldwert setzen, der die RGB-Farbwerte angibt. Diese Funktion können Sie in Verbindung mit dem Farbfeld verwenden, um einem Benutzer die Möglichkeit zu geben, eine Farbe mit einem Farbwähler festzulegen. Anschließend können Sie diese Farbe einer Ansichtskomponente zuweisen, zum Beispiel dem Text in einer Spalte. Weitere Informationen zur Verwendung dieser Funktion, um das Anpassen von Ansichtsfarben zu ermöglichen, finden Sie unter "Benutzern ermöglichen, Farben in einer Ansicht festzulegen".

Glossar